This is the mail archive of the
libc-alpha@sources.redhat.com
mailing list for the glibc project.
Re: glibc cvs broken?
- From: Andreas Schwab <schwab at suse dot de>
- To: libc-alpha at sources dot redhat dot com
- Date: Mon, 07 Oct 2002 12:06:12 +0200
- Subject: Re: glibc cvs broken?
- References: <200209291122.HAA02597@bromo.msbb.uc.edu>
Jack Howarth <howarth@bromo.msbb.uc.edu> writes:
|> make[1]: Entering directory `/home/howarth/libc'
|> ./aclocal.m4:19: error: m4_defn: undefined macro: _m4_divert_diversion
|> aclocal.m4:33: AC_CHECK_SYMBOL is expanded from...
|> ./aclocal.m4:19: the top level
With the following patch the glibc configure scripts work again with
autoconf 2.53+.
2002-10-07 Andreas Schwab <schwab@suse.de>
* aclocal.m4: Fix for autoconf 2.53.
* configure.in: Likewise. Require autoconf 2.53.
Index: aclocal.m4
===================================================================
RCS file: /cvs/glibc/libc/aclocal.m4,v
retrieving revision 1.17
diff -u -p -a -u -p -a -r1.17 aclocal.m4
--- aclocal.m4 11 Jun 2001 12:32:44 -0000 1.17
+++ aclocal.m4 24 Sep 2002 08:22:41 -0000
@@ -3,20 +3,22 @@ dnl which appears in configure.in before
dnl Each sysdep configure.in does GLIBC_PROVIDES first, to avoid any
dnl AC_REQUIREs or AC_BEFOREs duplicating their code.
dnl
-define([AC_FD_MSG],6)dnl Autoconf lossage.
-define([AC_FD_CC],5)dnl Autoconf lossage.
-AC_DEFUN([GLIBC_PROVIDES], [dnl
+define([GLIBC_PROVIDES], [dnl
AC_PROVIDE([AC_PROG_INSTALL])dnl
AC_PROVIDE([AC_PROG_RANLIB])dnl
AC_PROVIDE([AC_PROG_CC])dnl
AC_PROVIDE([AC_PROG_CPP])dnl
-define([AC_LANG], [C])dnl
-# This file is generated from configure.in by Autoconf. DO NOT EDIT!
+define([AS_MESSAGE_LOG_FD],5)dnl
+define([AS_MESSAGE_FD],6)dnl
+AS_INIT()dnl
+m4_divert_text([HEADER-COMMENT],
+[@%:@ This file is generated from configure.in by Autoconf. DO NOT EDIT!])
+AC_LANG(C)dnl
])dnl
dnl
dnl Check for a symbol
dnl
-AC_DEFUN(AC_CHECK_SYMBOL, [dnl
+AC_DEFUN([AC_CHECK_SYMBOL], [dnl
AC_MSG_CHECKING(for $1)
AC_CACHE_VAL(ac_cv_check_symbol_$1, [dnl
AC_TRY_LINK(,
@@ -36,7 +38,7 @@ dnl
dnl Locate a program and check that its version is acceptable.
dnl AC_PROG_CHECK_VER(var, namelist, version-switch,
dnl [version-extract-regexp], version-glob [, do-if-fail])
-AC_DEFUN(AC_CHECK_PROG_VER,
+AC_DEFUN([AC_CHECK_PROG_VER],
[AC_CHECK_PROGS([$1], [$2])
if test -z "[$]$1"; then
ac_verc_fail=yes
@@ -63,42 +65,10 @@ fi])
])
dnl These modifications are to allow for an empty cross compiler tree.
-dnl In the situation that cross-linking is impossible, the variable
-dnl `cross_linkable' will be substituted with "yes".
-dnl The vercheck macros are expected to have been called already.
-AC_DEFUN(AC_PROG_CC_LOCAL,
-[AC_BEFORE([$0], [AC_PROG_CPP])dnl
-
-AC_PROG_CC_WORKS_LOCAL
-AC_PROG_CC_GNU
-if test $ac_cv_prog_gcc != yes; then
- AC_MSG_ERROR([GNU libc must be compiled using GNU CC])
-fi
-])
-
-AC_DEFUN(AC_PROG_CC_WORKS_LOCAL,
-[AC_MSG_CHECKING([whether the C compiler ($CC $CFLAGS $LDFLAGS) works])
-AC_CACHE_VAL(ac_cv_prog_cc_works,
-[AC_LANG_SAVE
-AC_LANG_C
-AC_TRY_COMPILER([main(){return(0);}], ac_cv_prog_cc_works, ac_cv_prog_cc_cross)
-AC_LANG_RESTORE])
-AC_MSG_RESULT($ac_cv_prog_cc_works)
-if test $ac_cv_prog_cc_works = no; then
- cross_linkable=no
- ac_cv_prog_cc_cross=yes
-dnl AC_MSG_ERROR([installation or configuration problem: C compiler cannot create executables.])
-else
- cross_linkable=yes
-fi
-AC_CACHE_CHECK(
-[whether the C compiler ($CC $CFLAGS $LDFLAGS) is a cross-compiler],
-ac_cv_prog_cc_cross, [:])
-AC_SUBST(cross_linkable)
-cross_compiling=$ac_cv_prog_cc_cross
+define([_AC_COMPILER_EXEEXT], [EXEEXT=
])
-AC_DEFUN(LIBC_PROG_FOO_GNU,
+AC_DEFUN([LIBC_PROG_FOO_GNU],
[# Most GNU programs take a -v and spit out some text including
# the word 'GNU'. Some try to read stdin, so give them /dev/null.
if $1 -o conftest -v </dev/null 2>&1 | grep GNU > /dev/null 2>&1; then
@@ -108,7 +78,7 @@ else
fi
rm -fr contest*])
-AC_DEFUN(LIBC_PROG_BINUTILS,
+AC_DEFUN([LIBC_PROG_BINUTILS],
[# Was a --with-binutils option given?
if test -n "$path_binutils"; then
# Make absolute; ensure a single trailing slash.
Index: configure.in
===================================================================
RCS file: /cvs/glibc/libc/configure.in,v
retrieving revision 1.355
diff -u -p -a -u -p -a -r1.355 configure.in
--- configure.in 15 Sep 2002 02:20:14 -0000 1.355
+++ configure.in 24 Sep 2002 08:23:10 -0000
@@ -1,6 +1,6 @@
dnl Process this file with autoconf to produce a configure script.
AC_REVISION([$CVSid$])
-AC_PREREQ(2.13)dnl dnl Minimum Autoconf version required.
+AC_PREREQ(2.53)dnl dnl Minimum Autoconf version required.
AC_INIT(include/features.h)
AC_CONFIG_HEADER(config.h)
AC_CONFIG_AUX_DIR(scripts)
@@ -486,7 +486,7 @@ while test $# -gt 0; do
esac
# Report each name as we discover it, so there is no long pause in output.
- echo $ac_n "$name $ac_c" >&AC_FD_MSG
+ echo $ECHO_N "$name $ECHO_C" >&AC_FD_MSG
name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
@@ -579,7 +579,7 @@ if test "$PWD_P" = no; then
fi
# These programs are version sensitive.
-AC_REQUIRE([AC_CHECK_TOOL_PREFIX])dnl
+AC_CHECK_TOOL_PREFIX
AC_CHECK_PROG_VER(CC, ${ac_tool_prefix}gcc ${ac_tool_prefix}cc, -v,
[version \([egcygnustpi-]*[0-9.]*\)], [3.[2-9]*],
critic_missing="$critic_missing gcc")
@@ -608,8 +608,7 @@ AC_CHECK_PROG_VER(SED, sed, --version,
[3.0[2-9]*|3.[1-9]*|[4-9]*],
SED=: aux_missing="$aux_missing sed")
-AC_PROG_CC_LOCAL
-AC_CANONICAL_BUILD
+AC_PROG_CC
if test $host != $build; then
AC_CHECK_PROGS(BUILD_CC, gcc cc)
fi
@@ -1692,7 +1691,7 @@ AC_DEFUN(LIBC_KERNEL_ID, [dnl
])dnl
AC_CACHE_CHECK(OS release for uname, libc_cv_uname_release, [dnl
-AC_REQUIRE([LIBC_KERNEL_ID])dnl
+LIBC_KERNEL_ID
changequote(,)dnl
kernel_release=`echo "$kernel_id" | sed 's/^[^0-9.]*\([0-9.]*\).*$/\1/'`
changequote([,])dnl
@@ -1710,7 +1709,7 @@ changequote([,])dnl
uname_release="$libc_cv_uname_release"
AC_CACHE_CHECK(OS version for uname, libc_cv_uname_version, [dnl
-AC_REQUIRE([LIBC_KERNEL_ID])dnl
+LIBC_KERNEL_ID
changequote(,)dnl
kernel_version=`echo "$kernel_id" | sed 's/^[^#]*#\([0-9]*\).*$/\1/'`
changequote([,])dnl
Andreas.
--
Andreas Schwab, SuSE Labs, schwab@suse.de
SuSE Linux AG, Deutschherrnstr. 15-19, D-90429 Nürnberg
Key fingerprint = 58CA 54C7 6D53 942B 1756 01D3 44D5 214B 8276 4ED5
"And now for something completely different."