This is the mail archive of the libc-hacker@sources.redhat.com mailing list for the glibc project.

Note that libc-hacker is a closed list. You may look at the archives of this list, but subscription and posting are not open.


Index Nav: [Date Index] [Subject Index] [Author Index] [Thread Index]
Message Nav: [Date Prev] [Date Next] [Thread Prev] [Thread Next]
Other format: [Raw text]

[PATCH] Profile implemented for SuperH


Hello, 

I've implemented profiler for SuperH architecture.  It has been tested
with GCC changes.

I've put _mcount.S under sysdeps/unix/sysv/linux/sh/, but it might
be upper directory.

Besides, there's small fix for linuxthreads for SuperH.

ChangeLog
2001-12-12  NIIBE Yutaka  <gniibe@m17n.org>

	* sysdeps/unix/sysv/linux/sh/Makefile (sysdep_routines): Add
	_mcount.
	* sysdeps/unix/sysv/linux/sh/_mcount.S: New file.

	* sysdeps/sh/sysdep.h (CALL_MCOUNT): Implemented.

	* sysdeps/sh/machine-gmon.h: Remove "NOTYET" comment,
	as we are ready.

linuxthreads/ChangeLog
2001-12-12  NIIBE Yutaka  <gniibe@.m17n.org>

	* sysdeps/sh/pt-machine.h (INIT_THREAD_SELF): Added __volatile__
	qualifier to be safe.

--- linuxthreads/sysdeps/sh/pt-machine.h	2001/07/26 01:32:01	1.5
+++ linuxthreads/sysdeps/sh/pt-machine.h	2001/12/12 08:45:08
@@ -53,4 +53,4 @@ struct _pthread_descr_struct;
 
 /* Initialize the thread-unique value.  */
 #define INIT_THREAD_SELF(descr, nr) \
-  ({ __asm__("ldc %0,gbr" : : "r" (descr));})
+  ({ __asm__ __volatile__("ldc %0,gbr" : : "r" (descr));})
--- sysdeps/sh/machine-gmon.h	2001/07/06 04:56:03	1.2
+++ sysdeps/sh/machine-gmon.h	2001/12/12 08:45:09
@@ -17,8 +17,6 @@
    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
    02111-1307 USA.  */
 
-/* NOTYET  */
-
 /* We must not pollute the global namespace.  */
 #define mcount_internal __mcount_internal
 
--- sysdeps/sh/sysdep.h	2001/07/06 04:56:03	1.2
+++ sysdeps/sh/sysdep.h	2001/12/12 08:45:09
@@ -60,7 +60,15 @@
 
 /* If compiled for profiling, call `mcount' at the start of each function.  */
 #ifdef	PROF
-#define CALL_MCOUNT	/* NOTYET */
+#define CALL_MCOUNT					\
+	mov.l	1f,r1;					\
+	sts.l	pr,@-r15;				\
+	mova	2f,r0;					\
+	jmp	@r1;					\
+	 lds	r0,pr;					\
+	.align	2;					\
+1:	.long	mcount;					\
+2:	lds.l	@r15+,pr
 #else
 #define CALL_MCOUNT		/* Do nothing.  */
 #endif
--- sysdeps/unix/sysv/linux/sh/Makefile	2001/09/25 01:30:37	1.2
+++ sysdeps/unix/sysv/linux/sh/Makefile	2001/12/12 08:45:10
@@ -1,3 +1,7 @@
+ifeq ($(subdir),gmon)
+sysdep_routines += _mcount
+endif
+
 ifeq ($(subdir),io)
 sysdep_routines += pipe
 endif
--- sysdeps/unix/sysv/linux/sh/_mcount.S	Tue Dec  4 19:42:15 2001
+++ sysdeps/unix/sysv/linux/sh/_mcount.S	Wed Dec 12 17:44:52 2001
@@ -0,0 +1,67 @@
+/* Machine-specific calling sequence for `mcount' profiling function.  SuperH
+   Copyright (C) 2001 Free Software Foundation, Inc.
+   Contributed by NIIBE Yutaka <gniibe@m17n.org>
+   This file is part of the GNU C Library.
+
+   The GNU C Library is free software; you can redistribute it and/or
+   modify it under the terms of the GNU Lesser General Public
+   License as published by the Free Software Foundation; either
+   version 2.1 of the License, or (at your option) any later version.
+
+   The GNU C Library is distributed in the hope that it will be useful,
+   but WITHOUT ANY WARRANTY; without even the implied warranty of
+   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
+   Lesser General Public License for more details.
+
+   You should have received a copy of the GNU Lesser General Public
+   License along with the GNU C Library; if not, write to the Free
+   Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
+   02111-1307 USA.  */
+
+#include <sysdep.h>
+
+	ASM_GLOBAL_DIRECTIVE C_SYMBOL_NAME(_mcount)
+	ASM_TYPE_DIRECTIVE (C_SYMBOL_NAME(_mcount),function)
+	.align	5
+C_LABEL(_mcount)
+	/* Save registers.  */
+	mov.l	r4,@-r15
+	mov.l	r5,@-r15
+	mov.l	r6,@-r15
+	mov.l	r7,@-r15
+	sts.l	pr,@-r15
+
+	mov.l	@(20,r15),r4
+	sts	pr,r5
+
+#ifdef SHARED
+	mov.l	0f,r1
+	mova	0f,r0
+	add	r1,r0
+	mov.l	1f,r1
+	mov.l	@(r0,r1),r1
+#else
+	mov.l	1f,r1
+#endif
+	jsr	@r1
+	 nop
+
+	/* Pop the saved registers.  */
+	lds.l	@r15+,pr
+	mov.l	@r15+,r7
+	mov.l	@r15+,r6
+	mov.l	@r15+,r5
+	rts
+	 mov.l	@r15+,r4
+
+	.align 2
+#ifdef SHARED
+0:	.long	_GLOBAL_OFFSET_TABLE_
+1:	.long	C_SYMBOL_NAME(__mcount_internal)@GOT
+#else
+1:	.long	C_SYMBOL_NAME(__mcount_internal)
+#endif
+ASM_SIZE_DIRECTIVE(C_SYMBOL_NAME(_mcount))
+
+#undef mcount
+weak_alias (_mcount, mcount)
-- 


Index Nav: [Date Index] [Subject Index] [Author Index] [Thread Index]
Message Nav: [Date Prev] [Date Next] [Thread Prev] [Thread Next]