inilex.l

   1 %{
   2 /*
   3  * Copyright (c) 2000, Red Hat, Inc.
   4  *
   5  *     This program is free software; you can redistribute it and/or modify
   6  *     it under the terms of the GNU General Public License as published by
   7  *     the Free Software Foundation; either version 2 of the License, or
   8  *     (at your option) any later version.
   9  *
  10  *     A copy of the GNU General Public License can be found at
  11  *     http://www.gnu.org/
  12  *
  13  * Written by DJ Delorie <dj@cygnus.com>
  14  *
  15  */
  16
  17 /* tokenize the setup.ini files.  We parse a string which we've
  18    previously downloaded.  The program must call ini_init() to specify
  19    that string. */
  20
  21 #include "win32.h"
  22 #include <string.h>
  23
  24 #include "ini.h"
  25 #include "iniparse.h"
  26 #include "String++.h"
  27
  28 #define YY_INPUT(buf,result,max_size) { result = ini_getchar(buf, max_size); }
  29
  30 static int ini_getchar(char *buf, int max_size);
  31 static void ignore_line (void);
  32
  33 %}
  34
  35 /*%option debug */
  36 %option noyywrap
  37 %option yylineno
  38 %option never-interactive
  39
  40 STR     [a-zA-Z0-9_./+-]+
  41
  42 %%
  43
  44 \"[^"]*\"               { yylval = new char [strlen (yytext+1) + 1];
  45                           strcpy (yylval, yytext+1);
  46                           yylval[strlen (yylval)-1] = 0;
  47                           return STRING; }
  48
  49 "setup-timestamp:"      return SETUP_TIMESTAMP;
  50 "setup-version:"        return SETUP_VERSION;
  51 "version:"              return PACKAGEVERSION;
  52 "install:"              return INSTALL;
  53 "source:"               return SOURCE;
  54 "sdesc:"                return SDESC;
  55 "ldesc:"                return LDESC;
  56
  57 "category:"             return CATEGORY;
  58 "requires:"             return REQUIRES;
  59
  60 "apath:"                return APATH;
  61 "ppath:"                return PPATH;
  62
  63 "include-setup:"        return INCLUDE_SETUP;
  64
  65 "download-url:"         return DOWNLOAD_URL;
  66
  67 ^{STR}":"               ignore_line ();
  68
  69 "[curr]"                return T_CURR;
  70 "[test]"                return T_TEST;
  71 "[exp]"                 return T_TEST;
  72 "[prev]"                return T_PREV;
  73 "["{STR}"]"             return T_UNKNOWN;
  74
  75 {STR}                   { yylval = new char [strlen(yytext) + 1];
  76                           strcpy (yylval, yytext);
  77                           return STRING; }
  78
  79 [ \t\r]+                /* do nothing */;
  80
  81 "#".*\n                 { return '\n'; }
  82
  83 \n                      { return *yytext; }
  84 .                       { return *yytext; }
  85
  86 %%
  87
  88 #include "io_stream.h"
  89
  90 static io_stream *input_stream = 0;
  91 extern char *parse_mirror;
  92
  93 void
  94 ini_init(io_stream *stream, String const &mirror)
  95 {
  96   input_stream = stream;
  97   if (parse_mirror)
  98     delete[] parse_mirror;
  99   parse_mirror = mirror.cstr();
 100 }
 101
 102 static int
 103 ini_getchar(char *buf, int max_size)
 104 {
 105   if (input_stream)
 106     {
 107       ssize_t len = input_stream->read (buf, max_size);
 108       if (len < 1)
 109         {
 110           len = 0;
 111           input_stream = 0;
 112         }
 113       return len;
 114     }
 115   return 0;
 116 }
 117
 118 static void
 119 ignore_line ()
 120 {
 121   char c;
 122   while ((c = yyinput ()))
 123     {
 124       if (c == EOF)
 125         return;
 126       if (c == '\n')
 127         return;
 128     }
 129 }